MacWarehouse Macintosh Games/MacWarehouse Macintosh Games.iso/AMBER demo/AMBER-Journeys Beyond™ Patch 1c/00103_generic domain rules.ls

Text File | 1997-02-19 | 13.8 KB | 475 lines

on cursorOff
  global colorcrsr, YugoCursors, gCursorSwitch
  if objectp(colorcrsr) then
    colorcrsr(mGetSetCursor, getProp(YugoCursors, #noCursor))
    set gCursorSwitch to #off
  else
    cursor(200)
    set gCursorSwitch to #off
  end if
end

on cursorOn
  global colorcrsr, YugoCursors, thisCursor, gCursorSwitch
  if gCursorSwitch = #off then
    if objectp(colorcrsr) then
      colorcrsr(mGetSetCursor, getProp(YugoCursors, thisCursor))
    else
      castCursor(getProp(YugoCursors, thisCursor))
    end if
    set gCursorSwitch to #on
  end if
end

on castCursor cursorID
  set myCursorOffset to 1200
  if integerp(cursorID) then
    set whichCursor to cursorID - 6000
  else
    exit
  end if
  set cMask to myCursorOffset + (whichCursor * 2)
  cursor([cMask - 1, cMask])
end

on killVideo
  global lastScoreSprite
  set vidSprite to 44
  set the movieRate of sprite vidSprite to 0
  set the locV of sprite vidSprite to -500
  updateStage()
  set the castNum of sprite vidSprite to 7
  puppetSprite(vidSprite, 0)
end

on pushVideo
  set vidSprite to 44
  set the movieTime of sprite 44 to 0
  updateStage()
  set the movieRate of sprite 44 to 1
end

on setCurrentLocation suggestion
  return "Use the goTo() function instead.."
end

on goTo destination, transition
  global oPuppeteer, oStoryteller, builderWindow, gPreloading, gScanFinish, colorcrsr, YugoCursors, thisCursor, gCursorSwitch, gPeekAlertEnabled
  report(">starting 'goTo()'  (" & the timer & " ticks after mouseDown)")
  if objectp(colorcrsr) then
    colorcrsr(mGetSetCursor, getProp(YugoCursors, #noCursor))
  else
    cursor(200)
  end if
  set gCursorSwitch to #off
  if (destination = #destination) or (transition = #transition) then
    exit
  end if
  report(">cursorOff done (" & the timer & " ticks)")
  setAt(getProp(the lsStateData of oStoryteller, #previousLocation), 1, getAt(getProp(the lsStateData of oStoryteller, #currentLocation), 1))
  setAt(getProp(the lsStateData of oStoryteller, #currentLocation), 1, destination)
  if the castNum of sprite 44 <> 7 then
    killVideo()
    moveMovies(oPuppeteer)
  end if
  setTransition(oPuppeteer, transition)
  report(">'setTransition()' done (" & the timer & " ticks)")
  moveToLocation(oPuppeteer)
  report(">'moveToLocation()' done (" & the timer & " ticks)")
  if getPos(the windowList, builderWindow) then
    tell builderWindow
      refreshCast()
      refreshHotspots()
    end tell
  end if
  if gPreloading = 1 then
    preloadLocations()
    report(">preLoadLocations done (" & the timer & " ticks)")
  else
    report(">preLoadLocations skipped (" & the timer & " ticks)")
  end if
  report(" Available memory: " & the freeBytes / 1024 & " K (incl. " & the freeBlock / 1024 & " K block)")
  report("   :")
  set lsMoveCounter to getProp(the lsStateData of oStoryteller, #moveCount)
  set oldCount to getAt(lsMoveCounter, 1)
  setAt(lsMoveCounter, 1, oldCount + 1)
  return #OK
end

on goBack
  global oStoryteller
  goTo(getState(oStoryteller, #previousLocation), #backOff)
end

on idle
  global lastCursor, thisCursor, cursorOffset, castCursorList, maxCursor, oStoryteller, oPuppeteer, gCurrentHotspot, gItemInUse, domainIsReady, gPreloading, gStopTransitions, g16bit, gTransQuality, gFreezeInventory, gSoundPath, gOriginPoint, gMenuBottomY, gGammaLevel, gDeferredTransit
  if gDeferredTransit = #none then
    if domainIsReady then
      cursorOn()
      set thisCursor to #pointer
      set gCurrentHotspot to #none
      if the mouseV < gMenuBottomY then
        if the number of menus = 0 then
          installMenu(the number of cast "Amber menus")
          if gTransQuality = #none then
            set the checkMark of menuItem 1 of menu 3 to 1
          end if
          if gTransQuality = #Better then
            set the checkMark of menuItem 2 of menu 3 to 1
          end if
          if gTransQuality = #Best then
            set the checkMark of menuItem 3 of menu 3 to 1
          end if
          set the checkMark of menuItem (8 - the soundLevel) of menu 2 to 1
          if gGammaLevel <> "unknown" then
            set the checkMark of menuItem (8 - gGammaLevel) of menu 4 to 1
          end if
          set thisCursor to #pointer
        end if
      else
        installMenu(0)
      end if
      set mouseLoc to point(the mouseH, the mouseV) - gOriginPoint
      repeat with i in the lsLiveHotspots of oPuppeteer
        if inside(mouseLoc, getAt(i, 2)) then
          set myCursor to getAt(i, 1)
          if myCursor = #itemInUse then
            set thisCursor to getState(oStoryteller, #itemInUse)
          else
            set thisCursor to myCursor
          end if
          set gCurrentHotspot to i
          exit repeat
        end if
      end repeat
      if getState(oStoryteller, #tunedIn) = #inBetween then
        cycleStatic()
      end if
      prodVLoops()
      if getState(oStoryteller, #playerIsExaminingTelegram) = 1 then
        repeat with i = 25 to 36
          if the mouseCast = the castNum of sprite i then
            set thisCursor to #pointer
            exit repeat
          end if
        end repeat
      end if
      if thisCursor <> lastCursor then
        cursorDance(value(lastCursor & "To" & thisCursor))
        set lastCursor to thisCursor
      end if
      if getState(oStoryteller, #tunedIn) = #inBetween then
        cycleStatic()
      end if
    end if
  else
    do(gDeferredTransit)
    if gDeferredTransit contains "waiting" then
      if domainIsReady = 1 then
        if getState(oStoryteller, #currentDomain) = the last word in gDeferredTransit then
          set gDeferredTransit to #none
        end if
      end if
    end if
  end if
end

on cursorDance cursorList
  global colorcrsr, thisCursor, YugoCursors, gCPU
  if gCPU <> #PC then
    if not objectp(colorcrsr) then
      cursor(-1)
      set colorcrsr to ColorCursor(mnew)
    end if
  end if
  if not listp(cursorList) then
    if objectp(colorcrsr) then
      colorcrsr(mGetSetCursor, getProp(YugoCursors, thisCursor))
    else
      castCursor(getProp(YugoCursors, thisCursor))
    end if
    exit
  end if
  set flipBook to cursorList
  if objectp(colorcrsr) then
    repeat with flipper = 1 to count(flipBook)
      startTimer()
      colorcrsr(mGetSetCursor, getAt(flipBook, flipper))
      repeat while 2 > the timer
        nothing()
      end repeat
    end repeat
  else
    repeat with flipper = 1 to count(flipBook)
      startTimer()
      castCursor(getAt(flipBook, flipper))
      repeat while 2 > the timer
        nothing()
      end repeat
    end repeat
  end if
end

on inState stateVar, whichItem
  global oStoryteller
  set statelist to getProp(the lsStateData of oStoryteller, stateVar)
  if getPos(statelist, whichItem) = 0 then
    return 0
  else
    return 1
  end if
end

on trimState stateVar, whichItem
  global oStoryteller
  set statelist to getProp(the lsStateData of oStoryteller, stateVar)
  set myPos to getPos(statelist, whichItem)
  if myPos then
    deleteAt(statelist, myPos)
  end if
end

on addState stateVar, whichItem
  global oStoryteller
  set statelist to getProp(the lsStateData of oStoryteller, stateVar)
  set myPos to getPos(statelist, whichItem)
  if not myPos then
    append(statelist, whichItem)
  end if
end

on patchPalette
  global oFixPal
  oFixPal(mPatchIt)
end

on forcePalette palName
  global oPuppeteer, gCurrentPalette
  puppetPalette(palName, 60)
  set gCurrentPalette to #changeMe
  patchPalette()
end

on loadMultiFrames whichOnes
  global oPuppeteer
  set theFrames to getaProp(the lsMultiFrames of oPuppeteer, whichOnes)
  if listp(theFrames) then
    repeat with i in theFrames
      preLoadCast(i)
    end repeat
  else
    alert("Hey! There's no such list in lsMultiframes!")
  end if
end

on purgeMultiframes whichOnes
  global oPuppeteer
  set theFrames to getaProp(the lsMultiFrames of oPuppeteer, whichOnes)
  if listp(theFrames) then
    repeat with i in theFrames
      unLoadCast(i)
    end repeat
  else
    alert("Hey! There's no such list in lsMultiframes!")
  end if
end

on disablePeekAlert
  nothing()
end

on enablePeekAlert
  nothing()
end

on gammaFade upOrDown, howFast
  global gCPU
  if gCPU = #PC then
    exit
  end if
  set speedCodes to [#glacial: "4", #slow: "18", #fast: "36", #instant: "100"]
  set mySpeed to getaProp(speedCodes, howFast)
  if voidp(mySpeed) then
    set mySpeed to getProp(speedCodes, #fast)
  end if
  if upOrDown = #down then
    MonitorFade("down", mySpeed)
  else
    updateStage()
    MonitorFade("up", mySpeed)
  end if
end

on setColor howManybits
  set the colorDepth to howManybits
  if the colorDepth <> howManybits then
    if howManybits = 16 then
      set the colorDepth to 32
    else
      put "Sorry, Director sez the colorDepth is " & the colorDepth & " bits.."
    end if
  else
  end if
end

on initTelegramPuzzle
  global oStoryteller, oPuppeteer, lastScoreSprite, gOriginPoint
  set vGap to 68
  set hGap to 65
  set origin to point(220, 182) + gOriginPoint
  set firstSprite to 25
  set puzzlePieces to getProp(the lsMultiFrames of oPuppeteer, #telegram)
  set assignSprite to firstSprite
  repeat with thisPiece in puzzlePieces
    puppetSprite(assignSprite, 1)
    set the castNum of sprite assignSprite to thisPiece
    set the ink of sprite assignSprite to 8
    set assignSprite to assignSprite + 1
  end repeat
  set telegramStart to [5, 7, 12, 8, 11, 9, 6, 10, 2, 3, 1, 4]
  setProp(the lsStateData of oStoryteller, #telegramGuess, value(string(telegramStart)))
  repeat with i in telegramStart
    set workingNumber to getPos(telegramStart, i) - 1
    set skipRows to workingNumber / 4
    set skipColumns to workingNumber mod 4
    set the loc of sprite (firstSprite + i - 1) to origin + point(hGap * skipColumns, vGap * skipRows)
  end repeat
  puppetTransition(26)
  updateStage()
end

on moveMe
  global oStoryteller
  set chosenSprite to the clickOn
  set chosenPiece to chosenSprite - 24
  set theHole to 2
  set emptySprite to 26
  set moveTempo to 3
  set puzzleState to getProp(the lsStateData of oStoryteller, #telegramGuess)
  set isAdjacent to 0
  set chosenSpace to getPos(puzzleState, chosenPiece)
  set emptySpace to getPos(puzzleState, theHole)
  if (abs(chosenSpace - emptySpace) = 1) and (((chosenSpace - 1) / 4) = ((emptySpace - 1) / 4)) then
    set isAdjacent to #sameRow
  end if
  if (abs(chosenSpace - emptySpace) = 4) and (((chosenSpace - 1) mod 4) = ((emptySpace - 1) mod 4)) then
    set isAdjacent to #sameColumn
  end if
  if isAdjacent = 0 then
    repeat with nudge in [point(-1, -1), point(1, 1)]
      set the loc of sprite chosenSprite to the loc of sprite chosenSprite + nudge
      updateStage()
      wait(3)
    end repeat
  else
    soundEffect(#movePaper, 50)
    set chosenLoc to the loc of sprite chosenSprite
    if isAdjacent = #sameRow then
      set targetH to the locH of sprite emptySprite
      if the locH of sprite chosenSprite > targetH then
        set currentH to the locH of sprite chosenSprite
        repeat while currentH > targetH
          set theTix to the ticks
          set the locH of sprite chosenSprite to currentH
          updateStage()
          set currentH to currentH - 8
          repeat while the ticks < (theTix + moveTempo)
            nothing()
          end repeat
        end repeat
      else
        set currentH to the locH of sprite chosenSprite
        repeat while currentH < targetH
          set theTix to the ticks
          set the locH of sprite chosenSprite to currentH
          updateStage()
          set currentH to currentH + 8
          repeat while the ticks < (theTix + moveTempo)
            nothing()
          end repeat
        end repeat
      end if
      set the locH of sprite chosenSprite to targetH
      updateStage()
    else
      set targetV to the locV of sprite emptySprite
      if the locV of sprite chosenSprite > targetV then
        set currentV to the locV of sprite chosenSprite
        repeat while currentV > targetV
          set theTix to the ticks
          set the locV of sprite chosenSprite to currentV
          updateStage()
          set currentV to currentV - 8
          repeat while the ticks < (theTix + moveTempo)
            nothing()
          end repeat
        end repeat
      else
        set currentV to the locV of sprite chosenSprite
        repeat while currentV < targetV
          set theTix to the ticks
          set the locV of sprite chosenSprite to currentV
          updateStage()
          set currentV to currentV + 8
          repeat while the ticks < (theTix + moveTempo)
            nothing()
          end repeat
        end repeat
      end if
      set the locV of sprite chosenSprite to targetV
      updateStage()
    end if
    set the loc of sprite emptySprite to chosenLoc
    updateStage()
    set holePos to getPos(puzzleState, theHole)
    set piecePos to getPos(puzzleState, chosenPiece)
    if holePos > piecePos then
      deleteAt(puzzleState, piecePos)
      addAt(puzzleState, holePos, chosenPiece)
      deleteAt(puzzleState, holePos - 1)
      addAt(puzzleState, piecePos, theHole)
    else
      deleteAt(puzzleState, holePos)
      addAt(puzzleState, piecePos, theHole)
      deleteAt(puzzleState, piecePos - 1)
      addAt(puzzleState, holePos, chosenPiece)
    end if
    if puzzleState = [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12] then
      setState(oStoryteller, #showMontage, 1)
      setTransition(oPuppeteer, #fadeIn)
      updateDisplay(oPuppeteer)
    end if
  end if
end

on reportsprites
  repeat with i = 1 to 48
    set myCast to the castNum of sprite i
    if (myCast <> 7) and (myCast <> 6) then
      put "spr " & i & " cast " & myCast & ": " & the name of cast myCast
    end if
  end repeat
  put ":"
end

on reportloaded
  repeat with i = 1 to the number of castMembers
    if the loaded of cast i = 1 then
      put i & ": " & the name of cast i
    end if
  end repeat
  put ":"
end

on reportPuppets
  repeat with i = 1 to 48
    if the puppet of sprite i then
      put i
    end if
  end repeat
end

on clearTransitions
  puppetTransition(0, 0, 0, 1)
end